وحدة حساس الحركة MPU6050 (جيروسكوب + تسارع)

ميزان مائي رقمي: يكشف ميلان اللوحة

تقيس الوحدة ميلان اللوحة. عندما تكون مسطحة تماماً يضيء الليد الأخضر في المنتصف، وعند الميل لليسار يضيء الأصفر الأيسر، وعند الميل لليمين يضيء الأصفر الأيمن.

المكونات المطلوبة

• وحدة MPU6050 (جيروسكوب + تسارع)
• لوحة Arduino UNO R3
• لوحة تجارب (بريدبورد)
• أسلاك توصيل (جامبر)
• 3 ليدات ملونة
• مقاومات 220Ω (3 قطع)

مخطط الدائرة

ملاحظة: الرجل الطويلة في الـ LED هي الموجب (+)، وتتصل بالمقاومة. والرجل القصيرة (−) تتصل بخط الأرضي GND.

جدول التوصيل

الكود البرمجي

#include <Wire.h>

const int MPU_ADDR = 0x68;
const int leftLed = 2;
const int centerLed = 3;
const int rightLed = 4;

int16_t readWord() {
  int16_t hi = Wire.read();
  int16_t lo = Wire.read();
  return (hi << 8) | lo;
}

void setup() {
  pinMode(leftLed, OUTPUT);
  pinMode(centerLed, OUTPUT);
  pinMode(rightLed, OUTPUT);

  Wire.begin();
  Wire.beginTransmission(MPU_ADDR);
  // إيقاظ الحساس
  Wire.write(0x6B);
  Wire.write(0);
  Wire.endTransmission(true);
}

void loop() {
  Wire.beginTransmission(MPU_ADDR);
  // بداية قراءة التسارع
  Wire.write(0x3B);
  Wire.endTransmission(false);
  Wire.requestFrom(MPU_ADDR, 6, true);

  int16_t ax = readWord();
  int16_t ay = readWord();
  int16_t az = readWord();

  digitalWrite(leftLed,   (ax < -3000) ? HIGH : LOW);
  digitalWrite(rightLed,  (ax >  3000) ? HIGH : LOW);
  digitalWrite(centerLed, (ax >= -3000 && ax <= 3000) ? HIGH : LOW);
  delay(50);
}

طريقة التجربة

1. ركّب الدائرة كما في المخطط، ثم ارفع الكود إلى اللوحة.
2. ضع الوحدة مسطحة على الطاولة: يضيء الأخضر.
3. أمل الوحدة يميناً ويساراً بلطف وراقب الليدات.

إذا لم تعمل الدائرة؟

• إذا كان الاتجاه معكوساً (الميل لليمين يضيء الأيسر) بدّل مكان الليدين في الكود أو على البريدبورد.
• الحساس يقيس الميلان حول المحور X فقط في هذا المثال، فضع اللوحة بحيث يكون اتجاه الميل على هذا المحور.
• إذا لم تضئ أي ليد، تأكد من أسلاك SDA وSCL وأن الوحدة تعمل على العنوان 0x68.