حساس المسافة بالموجات فوق الصوتية HC-SR04

موقف سيارة ذكي: الليدات والبازر يتغيّران حسب القرب

الحساس يقيس بُعد أي جسم أمامه. إذا كان بعيداً (أكثر من 30 سم) يضيء الليد الأخضر، وإذا اقترب (15-30 سم) يضيء الأصفر، وإذا صار قريباً جداً (أقل من 15 سم) يضيء الأحمر ويُصدر البازر صوتاً. تماماً مثل حساس ركن السيارة.

المكونات المطلوبة

• حساس المسافة HC-SR04
• لوحة Arduino UNO R3
• لوحة تجارب (بريدبورد)
• أسلاك توصيل (جامبر)
• 3 ليدات: أخضر وأصفر وأحمر
• مقاومات 220Ω (3 قطع)
• بازر نشط 5 فولت (Active Buzzer)

مخطط الدائرة

ملاحظة: الرجل الطويلة في الـ LED هي الموجب (+)، وتتصل بالمقاومة. والرجل القصيرة (−) تتصل بخط الأرضي GND.

جدول التوصيل

الكود البرمجي

const int trigPin = 9;
const int echoPin = 10;
const int greenLed = 2;
const int yellowLed = 3;
const int redLed = 4;
const int buzzer = 5;

void setup() {
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);
  pinMode(greenLed, OUTPUT);
  pinMode(yellowLed, OUTPUT);
  pinMode(redLed, OUTPUT);
  pinMode(buzzer, OUTPUT);
}

long readDistanceCm() {
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  // نبضة قصيرة لإرسال الموجة
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);
  // زمن عودة الصدى
  long duration = pulseIn(echoPin, HIGH, 30000);
  // لا يوجد جسم أمام الحساس
  if (duration == 0) return 999;
  // تحويل الزمن إلى سنتيمتر
  return duration * 0.034 / 2;
}

void loop() {
  long d = readDistanceCm();
  digitalWrite(greenLed,  (d > 30) ? HIGH : LOW);
  digitalWrite(yellowLed, (d > 15 && d <= 30) ? HIGH : LOW);
  digitalWrite(redLed,    (d <= 15) ? HIGH : LOW);
  digitalWrite(buzzer,    (d <= 15) ? HIGH : LOW);
  delay(100);
}

طريقة التجربة

1. ركّب القطع على البريدبورد كما في المخطط، وتأكد أن الأرضي (GND) مشترك بين الليدات والبازر والحساس.
2. وصّل اللوحة بالكمبيوتر بكابل USB، وافتح برنامج Arduino IDE وانسخ الكود وارفعه.
3. قرّب يدك من الحساس تدريجياً وراقب تغيّر الليدات من الأخضر إلى الأصفر إلى الأحمر مع صوت البازر.

إذا لم تعمل الدائرة؟

• إذا لم تضئ أي ليد: تأكد أن الرجل الطويلة للـ LED متصلة بالمقاومة وليست بالأرضي.
• إذا ظلّ الليد الأخضر مضاءً دائماً: تأكد من توصيل TRIG بـ D9 وECHO بـ D10 وعدم تبديلهما.
• الحساس لا يقرأ الأجسام الناعمة أو المائلة بشكل جيد، فجرّب بكتاب أو كف اليد.