شاشة OLED مقاس 0.96 إنش I2C

لوحة عرض صغيرة: نص وعدّاد ثوانٍ وشريط تقدم

تعرض الشاشة نصاً وعدّاداً للثواني وشريط تقدم يتحرك، بينما يومض الليد الأخضر كل نصف ثانية. وهي مدخلك لعرض قراءات أي حساس مستقبلاً.

المكونات المطلوبة

• شاشة OLED مقاس 0.96 إنش
• لوحة Arduino UNO R3
• لوحة تجارب (بريدبورد)
• أسلاك توصيل (جامبر)
• 2 ليدات ملونة
• مقاومات 220Ω (2 قطع)

مخطط الدائرة

ملاحظة: الرجل الطويلة في الـ LED هي الموجب (+)، وتتصل بالمقاومة. والرجل القصيرة (−) تتصل بخط الأرضي GND.

جدول التوصيل

الكود البرمجي

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

Adafruit_SSD1306 display(128, 64, &Wire, -1);

const int greenLed = 2;
const int redLed = 4;

void setup() {
  pinMode(greenLed, OUTPUT);
  pinMode(redLed, OUTPUT);

  // العنوان الشائع 0x3C
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    // الشاشة غير مكتشفة
    digitalWrite(redLed, HIGH);
    while (true) {}
  }
  display.setTextColor(SSD1306_WHITE);
}

void loop() {
  display.clearDisplay();

  display.setTextSize(2);
  display.setCursor(0, 0);
  display.println("STEM Lab");

  display.setTextSize(1);
  display.setCursor(0, 28);
  display.print("Seconds: ");
  display.println(millis() / 1000);

  // شريط تقدم يتحرك
  display.fillRect(0, 48, (millis() / 50) % 128, 10, SSD1306_WHITE);
  display.display();

  digitalWrite(greenLed, ((millis() / 500) % 2 == 0) ? HIGH : LOW);
}

طريقة التجربة

1. ركّب الدائرة كما في المخطط، ثم ارفع الكود إلى اللوحة.
2. ثبّت المكتبتين Adafruit SSD1306 وAdafruit GFX من Library Manager.
3. تظهر الرسالة والعدّاد على الشاشة. إذا لم تظهر شاشة يضيء الليد الأحمر.

إذا لم تعمل الدائرة؟

• إذا بقي الأحمر مضاءً والشاشة سوداء: تحقق من أسلاك SDA وSCL، وجرّب العنوان 0x3D بدل 0x3C في الكود.
• الشاشة تدعم الحروف الإنجليزية والأرقام افتراضياً، أما العربية فتحتاج خطوطاً خاصة.
• تأكد أن الشاشة من نوع I2C بأربعة أطراف (VCC وGND وSCL وSDA).